Interfacing Microchip 23K256 32KB SRAM SPI Memory with Arduino

My GPS Predictive Lap Timer Project needs more memory than the typical Arduino contains. However, it occurred to me that I could use a Microchip 23K256 32KB SRAM SPI memory chip and not need to revert to an Arduino Mega or beyond. So I purchased a few 23K256 chips and began an investigation into SPI. Simple, right?

I read the 23K256 datasheet and searched the web to see what others did in an attempt to get the chips to interface with the Arduino. The first problem was the chips have a maximum operating voltage of 3.6V. Easy, I could power them with the 3V3 pin from the Arduino.

The second problem was writing the SPI interface software. Luckily there’s plenty of examples scattered across the internet, including a slightly dated library in the Arduino Playground (1 of 2 links fail). So as I usually do, I kludged together a simple test program.

Here is my program:

#include <SPI.h>

//SRAM opcodes
#define RDSR 5
#define WRSR 1
#define READ 3
#define WRITE 2

uint8_t SpiRAMRead8(uint16_t address) {
  uint8_t read_byte;

  PORTB &= ~(1<<PORTB2); //set SPI_SS low
  SPI.transfer(READ);
  SPI.transfer((char)(address >> 8));
  SPI.transfer((char)address);
  read_byte = SPI.transfer(0xFF);
  PORTB |= (1<<PORTB2); //set SPI_SS high
  return read_byte;
}

void SpiRAMWrite8(uint16_t address, uint8_t data_byte) {
  PORTB &= ~(1<<PORTB2); //set SPI_SS low
  SPI.transfer(WRITE);
  SPI.transfer((char)(address >> 8));
  SPI.transfer((char)address);
  SPI.transfer(data_byte);
  PORTB |= (1<<PORTB2); //set SPI_SS high
}

void setup(void) {
  uint16_t addr;
  uint8_t i;

  Serial.begin(9600);
  SPI.begin();
  for (addr=0; addr<32; addr++) {
    SpiRAMWrite8(addr, (uint8_t)addr);
    Serial.print("Addr: ");
    Serial.print(addr);
    i = SpiRAMRead8(addr);
    Serial.print(" | Read: ");
    Serial.println((uint16_t)i);
  }
}

void loop() {
}

The third problem is the chips use low logic level voltage. From the datasheet, minimum HIGH is 0.7*Vcc (2.31V) while maximum is Vcc+0.3 (3.6V). LOW side maximum is 0.2*Vcc (0.72V). The 5V powered Arduino levels probably wouldn’t work. I couldn’t simply wire directly between the Arduino and 23K256, it would probably damage the 23K256.

So I used a SparkFun Logic Level Converter between the Arduino SPI Clock pin (D13) and MOSI pin (D11). And actually, the Chip Select pin (D10) should run through level conversion too. The 23K256 data out pin (MISO) doesn’t require conversion.

However, I couldn’t get the chip to function. My test program was returning values, but they were gibberish. Something was clearly wrong.

I experimented over the course of several days with substituting an Adafruit TXB0108 Bidirectional Level Shifter. I searched the web and discovered many people had similar problems getting these chips to operate. I even tried using a few resister pair/voltage dividers in place of the level shifter. I began to get very skeptical of anyone that claimed they made these chips work. I searched the web some more and re-read the datasheet (there’s also a Microchip Application Note). I added a 10K ohm pull-up resister to the CS pin, but still gibberish.

Eventually I swallowed my pride and wrote a “help-wanted” post on the Arduino Forum. A few responses later I recieved a solution! I needed to tie the 23K256 HOLD pin high. While the datasheet doesn’t specifically state that, after countless re-readings I’ll admit it hints at it.

Here is the wire routing I finally used:

Arduino--Logic Conv--23K256
D13------TXH/TXL-----6.SCK
D12------------------2.MISO
D11------TXH/TXL-----5.MOSI
D10------------------1.CS
3V3------LV
5V-------HV
GND------HV GND
GND------------------4.VSS
3V3------------------8.VCC
3V3------------------7.HOLD
3V3------[10KR]------1.CS

Next experiment is to see if the speed of the 23K256 chip is fast enough to allow a 10Hz GPS update rate with my GPS Predictive Lap Timer Project…